Bake 文件参考

Bake文件是用于定义使用docker buildx bake运行的工作流的文件。

文件格式

您可以使用以下文件格式定义Bake文件：

HashiCorp配置语言（HCL）
JSON
YAML（Compose文件）

默认情况下，Bake使用以下查找顺序来查找配置文件：

compose.yaml
compose.yml
docker-compose.yml
docker-compose.yaml
docker-bake.json
docker-bake.override.json
docker-bake.hcl
docker-bake.override.hcl

您可以使用--file标志显式指定文件位置。

$ docker buildx bake --file ../docker/bake.hcl --print

如果您没有显式指定文件，Bake会在当前工作目录中搜索该文件。如果找到多个Bake文件，则所有文件都会合并成一个定义。文件根据查找顺序合并。这意味着，如果您的项目同时包含compose.yaml文件和docker-bake.hcl文件，Bake会先加载compose.yaml文件，然后再加载docker-bake.hcl文件。

如果合并的文件包含重复的属性定义，则这些定义将根据属性合并或被最后一次出现覆盖。以下属性将被最后一次出现覆盖：

target.cache-to
target.dockerfile-inline
target.dockerfile
target.outputs
target.platforms
target.pull
target.tags
target.target

例如，如果compose.yaml和docker-bake.hcl都定义了tags属性，则使用docker-bake.hcl。

$ cat compose.yaml
services:
  webapp:
    build:
      context: .
      tags:
        - bar
$ cat docker-bake.hcl
target "webapp" {
  tags = ["foo"]
}
$ docker buildx bake --print webapp
{
  "group": {
    "default": {
      "targets": [
        "webapp"
      ]
    }
  },
  "target": {
    "webapp": {
      "context": ".",
      "dockerfile": "Dockerfile",
      "tags": [
        "foo"
      ]
    }
  }
}

所有其他属性都会合并。例如，如果compose.yaml和docker-bake.hcl都为labels属性定义了唯一的条目，则所有条目都将包含在内。同一标签的重复条目将被覆盖。

$ cat compose.yaml
services:
  webapp:
    build:
      context: .
      labels: 
        com.example.foo: "foo"
        com.example.name: "Alice"
$ cat docker-bake.hcl
target "webapp" {
  labels = {
    "com.example.bar" = "bar"
    "com.example.name" = "Bob"
  }
}
$ docker buildx bake --print webapp
{
  "group": {
    "default": {
      "targets": [
        "webapp"
      ]
    }
  },
  "target": {
    "webapp": {
      "context": ".",
      "dockerfile": "Dockerfile",
      "labels": {
        "com.example.foo": "foo",
        "com.example.bar": "bar",
        "com.example.name": "Bob"
      }
    }
  }
}

语法

Bake文件支持以下属性类型：

target：构建目标
group：构建目标的集合
variable：构建参数和变量
function：自定义Bake函数

您在Bake文件中将属性定义为分层块。您可以为属性分配一个或多个属性。

以下代码片段显示了一个简单的Bake文件的JSON表示形式。此Bake文件定义了三个属性：变量、组和目标。

{
  "variable": {
    "TAG": {
      "default": "latest"
    }
  },
  "group": {
    "default": {
      "targets": ["webapp"]
    }
  },
  "target": {
    "webapp": {
      "dockerfile": "Dockerfile",
      "tags": ["docker.io/username/webapp:${TAG}"]
    }
  }
}

在Bake文件的JSON表示形式中，属性是对象，属性是分配给这些对象的数值。

以下示例以HCL格式显示相同的Bake文件。

variable "TAG" {
  default = "latest"
}

group "default" {
  targets = ["webapp"]
}

target "webapp" {
  dockerfile = "Dockerfile"
  tags = ["docker.io/username/webapp:${TAG}"]
}

HCL是Bake文件的首选格式。除了语法差异外，HCL还可以让您使用JSON和YAML格式不支持的功能。

本文档中的示例使用HCL格式。

目标

目标反映单个docker build调用。考虑以下构建命令：

$ docker build \
  --file=Dockerfile.webapp \
  --tag=docker.io/username/webapp:latest \
  https://github.com/username/webapp

您可以在Bake文件中按如下方式表达此命令：

target "webapp" {
  dockerfile = "Dockerfile.webapp"
  tags = ["docker.io/username/webapp:latest"]
  context = "https://github.com/username/webapp"
}

下表显示了您可以分配给目标的完整属性列表：

名称	类型	描述
`args`	映射	构建参数
`annotations`	列表	导出器注释
`attest`	列表	构建证明
`cache-from`	列表	外部缓存源
`cache-to`	列表	外部缓存目标
`context`	字符串	位于指定路径或URL中的一组文件
`contexts`	映射	附加构建上下文
`dockerfile-inline`	字符串	内联Dockerfile字符串
`dockerfile`	字符串	Dockerfile位置
`inherits`	列表	继承其他目标的属性
`labels`	映射	镜像的元数据
`matrix`	映射	定义一组将目标分解成多个目标的变量。
`name`	字符串	使用矩阵时覆盖目标名称。
`no-cache-filter`	列表	禁用特定阶段的构建缓存
`no-cache`	布尔值	完全禁用构建缓存
`output`	列表	输出目标
`platforms`	列表	目标平台
`pull`	布尔值	始终拉取镜像
`secret`	列表	要公开给构建的密钥
`shm-size`	列表	`/dev/shm`的大小
`ssh`	列表	要公开给构建的SSH代理套接字或密钥
`tags`	列表	镜像名称和标签
`target`	字符串	目标构建阶段
`ulimits`	列表	Ulimit选项

`target.args`

使用args属性为目标定义构建参数。这与向构建命令传递--build-arg标志具有相同的效果。

target "default" {
  args = {
    VERSION = "0.0.0+unknown"
  }
}

您可以将args属性设置为使用null值。这样做会强制target使用Dockerfile中指定的ARG值。

variable "GO_VERSION" {
  default = "1.20.3"
}

target "webapp" {
  dockerfile = "webapp.Dockerfile"
  tags = ["docker.io/username/webapp"]
}

target "db" {
  args = {
    GO_VERSION = null
  }
  dockerfile = "db.Dockerfile"
  tags = ["docker.io/username/db"]
}

`target.annotations`

使用annotations属性，您可以向使用bake构建的镜像添加注释。密钥采用注释列表的形式，格式为KEY=VALUE。

target "default" {
  output = ["type=image,name=foo"]
  annotations = ["org.opencontainers.image.authors=dvdksn"]
}

与……相同

target "default" {
  output = ["type=image,name=foo,annotation.org.opencontainers.image.authors=dvdksn"]
}

默认情况下，注释将添加到镜像清单中。您可以通过在注释前添加前缀来配置注释级别，该前缀包含要注释的所有级别的逗号分隔列表。以下示例将注释添加到镜像索引和清单。

target "default" {
  output = ["type=image,name=foo"]
  annotations = ["index,manifest:org.opencontainers.image.authors=dvdksn"]
}

有关支持的级别的信息，请阅读指定注释级别。

`target.attest`

attest 属性允许您将构建声明应用于目标。此属性接受声明参数的长格式 CSV 版本。

target "default" {
  attest = [
    "type=provenance,mode=min",
    "type=sbom"
  ]
}

`target.cache-from`

构建缓存源。构建器从您指定的位置导入缓存。它使用Buildx 缓存存储后端，其工作方式与--cache-from标志相同。这采用列表值，因此您可以指定多个缓存源。

target "app" {
  cache-from = [
    "type=s3,region=eu-west-1,bucket=mybucket",
    "user/repo:cache",
  ]
}

`target.cache-to`

构建缓存导出目标。构建器将其构建缓存导出到您指定的位置。它使用Buildx 缓存存储后端，其工作方式与--cache-to标志相同。这采用列表值，因此您可以指定多个缓存导出目标。

target "app" {
  cache-to = [
    "type=s3,region=eu-west-1,bucket=mybucket",
    "type=inline"
  ]
}

`target.call`

指定要使用的前端方法。例如，前端方法允许您仅执行构建检查，而不是运行构建。这与--call标志相同。

target "app" {
  call = "check"
}

有关前端方法的更多信息，请参阅docker buildx build --call的 CLI 参考。

`target.context`

指定此目标要使用的构建上下文的路径。接受 URL 或目录路径。这与您传递给构建命令的构建上下文位置参数相同。

target "app" {
  context = "./src/www"
}

默认情况下，这将解析为当前工作目录 (".")。

$ docker buildx bake --print -f - <<< 'target "default" {}'
[+] Building 0.0s (0/0)
{
  "target": {
    "default": {
      "context": ".",
      "dockerfile": "Dockerfile"
    }
  }
}

`target.contexts`

附加构建上下文。这与--build-context标志相同。此属性采用映射，其中键导致命名的上下文，您可以在构建中引用这些上下文。

您可以指定不同类型的上下文，例如本地目录、Git URL，甚至是其他 Bake 目标。Bake 会根据上下文值的模式自动确定上下文的类型。

上下文类型	示例
容器镜像	`docker-image://alpine@sha256:0123456789`
Git URL	`https://github.com/user/proj.git`
HTTP URL	`https://example.com/files`
本地目录	`../path/to/src`
Bake 目标	`target:base`

固定镜像版本

# docker-bake.hcl
target "app" {
    contexts = {
        alpine = "docker-image://alpine:3.13"
    }
}

# Dockerfile
FROM alpine
RUN echo "Hello world"

使用本地目录

# docker-bake.hcl
target "app" {
    contexts = {
        src = "../path/to/source"
    }
}

# Dockerfile
FROM scratch AS src
FROM golang
COPY --from=src . .

使用另一个目标作为基础

注意
您应该优先使用常规多阶段构建而不是此选项。当您有多个 Dockerfile 难以轻松合并为一个时，可以使用此功能。

# docker-bake.hcl
target "base" {
    dockerfile = "baseapp.Dockerfile"
}
target "app" {
    contexts = {
        baseapp = "target:base"
    }
}

# Dockerfile
FROM baseapp
RUN echo "Hello world"

`target.dockerfile-inline`

将字符串值用作构建目标的内联 Dockerfile。

target "default" {
  dockerfile-inline = "FROM alpine\nENTRYPOINT [\"echo\", \"hello\"]"
}

dockerfile-inline优先于dockerfile属性。如果同时指定两者，Bake 将使用内联版本。

`target.dockerfile`

要用于构建的 Dockerfile 的名称。这与docker build命令的--file标志相同。

target "default" {
  dockerfile = "./src/www/Dockerfile"
}

默认情况下解析为"Dockerfile"。

$ docker buildx bake --print -f - <<< 'target "default" {}'
[+] Building 0.0s (0/0)
{
  "target": {
    "default": {
      "context": ".",
      "dockerfile": "Dockerfile"
    }
  }
}

`target.entitlements`

授权是构建过程运行所需的权限。

当前支持的授权为

network.host：允许构建使用访问主机网络的命令。在 Dockerfile 中，使用RUN --network=host来运行启用主机网络的命令。
security.insecure：允许构建在不受

target "integration-tests" {
  # this target requires privileged containers to run nested containers
  entitlements = ["security.insecure"]
}

启用授权需要两个步骤。首先，目标必须声明其所需的授权。其次，在调用bake命令时，用户必须通过传递--allow标志来授予授权，或者在交互式终端中出现提示时确认授权。这样做是为了确保用户了解他们授予构建过程的权限可能存在安全风险。

`target.inherits`

目标可以从其他目标继承属性。使用inherits从一个目标引用另一个目标。

在下面的示例中，app-dev目标指定了镜像名称和标签。app-release目标使用inherits来重用标签名称。

variable "TAG" {
  default = "latest"
}

target "app-dev" {
  tags = ["docker.io/username/myapp:${TAG}"]
}

target "app-release" {
  inherits = ["app-dev"]
  platforms = ["linux/amd64", "linux/arm64"]
}

inherits属性是一个列表，这意味着您可以重用多个其他目标的属性。在下面的示例中，app-release目标重用了app-dev和_release目标的属性。

target "app-dev" {
  args = {
    GO_VERSION = "1.20"
    BUILDX_EXPERIMENTAL = 1
  }
  tags = ["docker.io/username/myapp"]
  dockerfile = "app.Dockerfile"
  labels = {
    "org.opencontainers.image.source" = "https://github.com/username/myapp"
  }
}

target "_release" {
  args = {
    BUILDKIT_CONTEXT_KEEP_GIT_DIR = 1
    BUILDX_EXPERIMENTAL = 0
  }
}

target "app-release" {
  inherits = ["app-dev", "_release"]
  platforms = ["linux/amd64", "linux/arm64"]
}

当从多个目标继承属性并且存在冲突时，inherits列表中最后出现的目标优先。前面的示例为app-release目标两次定义了BUILDX_EXPERIMENTAL参数。它解析为0，因为_release目标出现在继承链的最后。

$ docker buildx bake --print app-release
[+] Building 0.0s (0/0)
{
  "group": {
    "default": {
      "targets": [
        "app-release"
      ]
    }
  },
  "target": {
    "app-release": {
      "context": ".",
      "dockerfile": "app.Dockerfile",
      "args": {
        "BUILDKIT_CONTEXT_KEEP_GIT_DIR": "1",
        "BUILDX_EXPERIMENTAL": "0",
        "GO_VERSION": "1.20"
      },
      "labels": {
        "org.opencontainers.image.source": "https://github.com/username/myapp"
      },
      "tags": [
        "docker.io/username/myapp"
      ],
      "platforms": [
        "linux/amd64",
        "linux/arm64"
      ]
    }
  }
}

`target.labels`

为构建分配镜像标签。这与docker build的--label标志相同。

target "default" {
  labels = {
    "org.opencontainers.image.source" = "https://github.com/username/myapp"
    "com.docker.image.source.entrypoint" = "Dockerfile"
  }
}

可以使用null值作为标签。如果这样做，构建器将使用 Dockerfile 中指定的标签值。

`target.matrix`

矩阵策略允许您根据指定的参数将单个目标分叉成多个不同的变体。这与[GitHub Actions 的矩阵策略]的工作方式类似。您可以使用此功能来减少 bake 定义中的重复。

matrix属性是一个参数名称到值列表的映射。Bake 将每个可能的组合值作为单独的目标构建。

每个生成的 target **必须**具有唯一的名称。要指定目标名称的解析方式，请使用name属性。

下面的示例将app目标解析为app-foo和app-bar。它还使用矩阵值来定义目标构建阶段。

target "app" {
  name = "app-${tgt}"
  matrix = {
    tgt = ["foo", "bar"]
  }
  target = tgt
}

$ docker buildx bake --print app
[+] Building 0.0s (0/0)
{
  "group": {
    "app": {
      "targets": [
        "app-foo",
        "app-bar"
      ]
    },
    "default": {
      "targets": [
        "app"
      ]
    }
  },
  "target": {
    "app-bar": {
      "context": ".",
      "dockerfile": "Dockerfile",
      "target": "bar"
    },
    "app-foo": {
      "context": ".",
      "dockerfile": "Dockerfile",
      "target": "foo"
    }
  }
}

多个轴

您可以在矩阵中指定多个键，以便在多个轴上分叉目标。使用多个矩阵键时，Bake 会构建每个可能的变体。

以下示例构建四个目标

app-foo-1-0
app-foo-2-0
app-bar-1-0
app-bar-2-0

target "app" {
  name = "app-${tgt}-${replace(version, ".", "-")}"
  matrix = {
    tgt = ["foo", "bar"]
    version = ["1.0", "2.0"]
  }
  target = tgt
  args = {
    VERSION = version
  }
}

每个矩阵目标的多个值

如果您想区分不仅仅是单个值的矩阵，可以使用映射作为矩阵值。Bake 为每个映射创建一个目标，您可以使用点表示法访问嵌套的值。

以下示例构建两个目标

app-foo-1-0
app-bar-2-0

target "app" {
  name = "app-${item.tgt}-${replace(item.version, ".", "-")}"
  matrix = {
    item = [
      {
        tgt = "foo"
        version = "1.0"
      },
      {
        tgt = "bar"
        version = "2.0"
      }
    ]
  }
  target = item.tgt
  args = {
    VERSION = item.version
  }
}

`target.name`

为使用矩阵策略的目标指定名称解析。以下示例将app目标解析为app-foo和app-bar。

target "app" {
  name = "app-${tgt}"
  matrix = {
    tgt = ["foo", "bar"]
  }
  target = tgt
}

`target.network`

指定整个构建请求的网络模式。这将覆盖 Dockerfile 中所有RUN指令的默认网络模式。接受的值为default、host和none。

通常，为构建步骤设置网络模式的更好方法是使用 Dockerfile 中的RUN --network=<value>。这样，您可以为单个构建步骤设置网络模式，并且所有构建 Dockerfile 的人都可以获得一致的行为，而无需向构建命令传递其他标志。

如果在 Bake 文件中将网络模式设置为host，则在调用bake命令时还必须授予network.host授权。这是因为host网络模式需要提升的权限，并且可能存在安全风险。您可以将--allow=network.host传递到docker buildx bake命令以授予授权，或者如果您使用的是交互式终端，则可以在出现提示时确认授权。

target "app" {
  # make sure this build does not access internet
  network = "none"
}

`target.no-cache-filter`

不要为指定的阶段使用构建缓存。这与docker build的--no-cache-filter标志相同。以下示例避免了foo构建阶段的构建缓存。

target "default" {
  no-cache-filter = ["foo"]
}

`target.no-cache`

构建镜像时不要使用缓存。这与docker build的--no-cache标志相同。

target "default" {
  no-cache = 1
}

`target.output`

导出构建输出的配置。这与--output标志相同。以下示例将目标配置为使用仅缓存输出。

target "default" {
  output = ["type=cacheonly"]
}

`target.platforms`

设置构建目标的目标平台。这与--platform标志相同。以下示例为三种架构创建多平台构建。

target "default" {
  platforms = ["linux/amd64", "linux/arm64", "linux/arm/v7"]
}

`target.pull`

配置构建器在构建目标时是否应尝试拉取镜像。这与docker build的--pull标志相同。以下示例强制构建器始终拉取构建目标中引用的所有镜像。

target "default" {
  pull = true
}

`target.secret`

定义要公开给构建目标的机密。这与--secret标志相同。

variable "HOME" {
  default = null
}

target "default" {
  secret = [
    "type=env,id=KUBECONFIG",
    "type=file,id=aws,src=${HOME}/.aws/credentials"
  ]
}

这允许您在 Dockerfile 中挂载机密。

RUN --mount=type=secret,id=aws,target=/root/.aws/credentials \
    aws cloudfront create-invalidation ...
RUN --mount=type=secret,id=KUBECONFIG,env=KUBECONFIG \
    helm upgrade --install

`target.shm-size`

设置使用RUN指令时为构建容器分配的共享内存大小。

格式为<number><unit>。number必须大于0。单位是可选的，可以是b（字节）、k（千字节）、m（兆字节）或g（千兆字节）。如果省略单位，系统将使用字节。

这与docker build的--shm-size标志相同。

target "default" {
  shm-size = "128m"
}

注意
在大多数情况下，建议让构建器自动确定适当的配置。只有在需要针对复杂构建场景进行特定性能调整时，才应考虑手动调整。

`target.ssh`

定义要公开给构建的 SSH 代理套接字或密钥。这与--ssh标志相同。如果需要在构建期间访问私有存储库，这将非常有用。

target "default" {
  ssh = ["default"]
}

FROM alpine
RUN --mount=type=ssh \
    apk add git openssh-client \
    && install -m 0700 -d ~/.ssh \
    && ssh-keyscan github.com >> ~/.ssh/known_hosts \
    && git clone [email protected]:user/my-private-repo.git

`target.tags`

用于构建目标的镜像名称和标签。这与--tag标志相同。

target "default" {
  tags = [
    "org/repo:latest",
    "myregistry.azurecr.io/team/image:v1"
  ]
}

`target.target`

设置目标构建阶段进行构建。这与--target标志相同。

target "default" {
  target = "binaries"
}

`target.ulimits`

使用RUN指令时，ulimits 会覆盖构建容器的默认 ulimits，并以软限制和硬限制的形式指定：<type>=<soft limit>[:<hard limit>]，例如

target "app" {
  ulimits = [
    "nofile=1024:1024"
  ]
}

注意
如果不提供hard limit，则soft limit将用于这两个值。如果没有设置ulimits，则它们将从守护进程上设置的默认ulimits继承。

注意
在大多数情况下，建议让构建器自动确定适当的配置。只有在需要针对复杂构建场景进行特定性能调整时，才应考虑手动调整。

组

组允许您一次调用多个构建（目标）。

group "default" {
  targets = ["db", "webapp-dev"]
}

target "webapp-dev" {
  dockerfile = "Dockerfile.webapp"
  tags = ["docker.io/username/webapp:latest"]
}

target "db" {
  dockerfile = "Dockerfile.db"
  tags = ["docker.io/username/db"]
}

如果组和目标都存在并且名称相同，则组优先。以下 bake 文件构建default组。Bake 忽略default目标。

target "default" {
  dockerfile-inline = "FROM ubuntu"
}

group "default" {
  targets = ["alpine", "debian"]
}
target "alpine" {
  dockerfile-inline = "FROM alpine"
}
target "debian" {
  dockerfile-inline = "FROM debian"
}

变量

HCL 文件格式支持变量块定义。您可以将变量用作 Dockerfile 中的构建参数，或将它们插入 Bake 文件中的属性值中。

variable "TAG" {
  default = "latest"
}

target "webapp-dev" {
  dockerfile = "Dockerfile.webapp"
  tags = ["docker.io/username/webapp:${TAG}"]
}

您可以为 Bake 文件中的变量分配默认值，也可以为其分配null值。如果分配null值，则 Buildx 将使用 Dockerfile 中的默认值。

您可以使用环境变量覆盖在 Bake 文件中设置的变量默认值。以下示例将TAG变量设置为dev，覆盖前面示例中显示的默认latest值。

$ TAG=dev docker buildx bake webapp-dev

内置变量

以下变量是 Bake 的内置变量，无需定义即可使用。

变量	描述
`BAKE_CMD_CONTEXT`	使用远程 Bake 文件构建时，保存主上下文。
`BAKE_LOCAL_PLATFORM`	返回当前平台的默认平台规范（例如：`linux/amd64`）。

使用环境变量作为默认值

您可以设置 Bake 变量，使用环境变量的值作为默认值。

variable "HOME" {
  default = "$HOME"
}

将变量内插到属性中

要将变量插入属性字符串值中，必须使用花括号。以下方法无效。

variable "HOME" {
  default = "$HOME"
}

target "default" {
  ssh = ["default=$HOME/.ssh/id_rsa"]
}

将变量用花括号括起来，放在您想要插入的位置。

  variable "HOME" {
    default = "$HOME"
  }

  target "default" {
-   ssh = ["default=$HOME/.ssh/id_rsa"]
+   ssh = ["default=${HOME}/.ssh/id_rsa"]
  }

在将变量插入属性之前，必须先在 bake 文件中声明它，如下例所示。

$ cat docker-bake.hcl
target "default" {
  dockerfile-inline = "FROM ${BASE_IMAGE}"
}
$ docker buildx bake
[+] Building 0.0s (0/0)
docker-bake.hcl:2
--------------------
   1 |     target "default" {
   2 | >>>   dockerfile-inline = "FROM ${BASE_IMAGE}"
   3 |     }
   4 |
--------------------
ERROR: docker-bake.hcl:2,31-41: Unknown variable; There is no variable named "BASE_IMAGE"., and 1 other diagnostic(s)
$ cat >> docker-bake.hcl

variable "BASE_IMAGE" {
  default = "alpine"
}

$ docker buildx bake
[+] Building 0.6s (5/5) FINISHED

函数

由 go-cty 提供的一组通用函数可用于 HCL 文件。

# docker-bake.hcl
target "webapp-dev" {
  dockerfile = "Dockerfile.webapp"
  tags = ["docker.io/username/webapp:latest"]
  args = {
    buildno = "${add(123, 1)}"
  }
}

此外，还支持用户自定义函数。

# docker-bake.hcl
function "increment" {
  params = [number]
  result = number + 1
}

target "webapp-dev" {
  dockerfile = "Dockerfile.webapp"
  tags = ["docker.io/username/webapp:latest"]
  args = {
    buildno = "${increment(123)}"
  }
}

注意
更多详情，请参阅用户自定义 HCL 函数页面。